[ACCEPTED]-How to repeat a statement N times (simple loop)-d

Accepted answer

Score: 10

Yes, it is possible

import std.stdio;
import std.traits;

void foo()
{
    writeln("Do It!");
}

void times(T,N)(N n, T action) if (isCallable!T && isIntegral!N)
{
    static if (ParameterTypeTuple!action.length == 1 
           && isIntegral!(ParameterTypeTuple!action[0]))
        foreach (i; 0 .. n)
            action(i);
    else
        foreach (i; 0 .. n)
            action();
}

void main(string[] args)
{
    10.times(&foo);
    10.times({writeln("Do It!");});
    10.times((uint n){writeln(n + 1, " Round");});
}

version with arguments 2 support:

import std.stdio;
import std.traits;

void foo()
{
    writeln("Do It!");
}

struct Step {
    alias n this;
    size_t n;
    this(size_t i)
    {
        n = i + 1;
    }
}

struct Index {
    alias n this;
    size_t n;
}

void times(T,N,A...)(N n, T action, A args) if (isCallable!T && isIntegral!N)
{
    alias PTTAction = ParameterTypeTuple!action;
    static if (PTTAction.length >= 1)
    {
        alias FP = PTTAction[0];
        static if (is(Index == FP) || is(Step == FP))
            foreach (i; 0 .. n)
                action(FP(i), args);
        else
            action(args);
    }
    else
        foreach (i; 0 .. n)
            action();
}

void main(string[] args)
{
    10.times(&foo);
    10.times({writeln("Do It!");});
    10.times((Step n){writeln(n, " Step");});
    10.times((Index n, string msg){writeln(n, msg);}, " Index");
    stdin.readln;
}

UPDATE:

for better performance you could 1 use alias template parametr for action:

void times(alias action,N)(N n) if (isCallable!action && isIntegral!N)
{
    static if (ParameterTypeTuple!action.length == 1 
           && isIntegral!(ParameterTypeTuple!action[0]))
        foreach (i; 0 .. n)
            action(i);
    else
        foreach (i; 0 .. n)
            action();
}

void main(string[] args)
{
    10.times!(foo);
    10.times!({writeln("Do It!");});
    10.times!((uint n){writeln(n + 1, " Round");});
}

Score: 4

Perhaps something like this?

void loop(int n, void delegate() func)
{
    foreach (i; 0 .. n)
    {
        func();
    }
}

Usage:

loop(10, {        
    writeln("Hello World!");
});

Source: stackoverflow.com

How do I connect to a database and loop over a recordset in C#?

Java For-Each Loop : Sort order

To understand: From PHP Array to Python?

Using lock statement within a loop in C#

All elements of An ArrayList change when a new one is added?

How to update glut window continuously?

PHP while loop add by 2

Why do some kernel programmers use goto instead of simple while loops?

How to add items to an array while looping through it?

FOR loop performance in PHP

Cookie Warning

We use cookies to improve the performance of the site. By staying on our site, you agree to the terms of use of cookies.